Separate engine/airframe hours on the various paints

[Medtner]

As far as I have seen the 3 Cessna models I have use the same airframe/engine hours (and the general condition).

I'm wondering if it is possible to make it so that at least some of the different paints I have can be separate airplanes (as the Cub's different versions with the floats, skis and tundras).
This would mean that I could have a consistently "new" Cessna, which I can treat accordingly, and which I perhaps only move from airport to airport without "cheating" in the airport-selection --- and also I could have a "trainer", which may be less new and which may be used for training and a little rougher use.
I can see many other potential uses for this.

Erik

[J van E]

This has been suggested and asked for before and A2A took note of it so maybe we will see this option in the (near) future. Until then you can save various states of planes by saving the backups which are made after ending a flight in FSX (in the Documents/A2A folder) and renaming/copying them whenever you want to fly another state.

[Medtner]

I guessed that I wasn't the first to have thought of this, but couldn't find anything here on the forum on it.
Glad to hear that there may be a way of doing this.

I will try what you described, though I'm not exactly sure what you meant. Are there any other posts here on the forum describing this?

Thanks,
Erik

[Gypsy Baron]

Here is the contents of a BATCH file I have been using to save the DAT files of my A2A B-17G paints that I fly regularly. The file can be modified to load/save DAT files for any of the other A2A aircraft whose DAT files reside in the "My Documents\<user name>\A2A\FSX\" folder or the equivalent path on a Xp system.

You can open the file in any text editor to make the changes specific to your system. There are
remarks "REM" statements in the file to help in understanding what is required to tailor the file to
your needs.

Here are those REM's:

Code: Select all

REM This batch file will save or load one of five different A2A B17G DAT files.
REM Sub-folders in the A2A\FSX\B17 folder and text files must be created first!

REM Create a sub-folder for each B17 paint you wish to save in the A2A\FSX\B17 folder.
REM In each sub-folder create a text file named "Loaded_Now.txt" that ID's the paint.
REM Example: Fearless Fosdick (91st BG) is loaded now!

REM A file named "f1.txt" and one named "Loaded_Now.txt" will be created in the 
REM A2A\FSX\B17 folder.the first time this file is run. These files are used
REM to prevent the current file from being saved in the wrong folder. The "OTHER"
REM option allows the current file to be unconditionally saved in the "Other" folder

REM The path names below must be set to your \Users\<user name>\Documents.
.
REM This file has been tested on my Win7 Pro x64 system and works properly.
REM Use mat your own risk. Backup your current DAT files as necessary. 
REM Created by Paul 'Gypsy Baron' Strogen - October 02, 2013

Here is the full listing of the file, which I named "loadSave-B17.bat and keep on my desktop so that I can easily load or save a DAT file before/after a flight.

Code: Select all

@echo off
REM This batch file will save or load one of five different A2A B17G DAT files.
REM Sub-folders in the A2A\FSX\B17 folder and text files must be created first!

REM Create a sub-folder for each B17 paint you wish to save in the A2A\FSX\B17 folder.
REM In each sub-folder create a text file named "Loaded_Now.txt" that ID's the paint.
REM Example: Fearless Fosdick (91st BG) is loaded now!

REM A file named "f1.txt" and one named "Loaded_Now.txt" will be created in the 
REM A2A\FSX\B17 folder.the first time this file is run. These files are used
REM to prevent the current file from being saved in the wrong folder. The "OTHER"
REM option allows the current file to be unconditionally saved in the "Other" folder

REM The path names below must be set to your \Users\<user name>\Documents.
.
REM This file has been tested on my Win7 Pro x64 system and works properly.
REM Use mat your own risk. Backup your current DAT files as necessary. 
REM Created by Paul 'Gypsy Baron' Strogen - October 02, 2013

title Load or Save A2A B-17G 

:start 
color 37
cls
echo This BAT file will Load or Save the B-17G DAT file
C:

REM Change the path below for your system!
REM Change the paint names to match yours

CD \Users\Gypsy Baron\Documents\A2A\FSX\B17
type loaded_now.txt >f1.txt
echo .
type loaded_now.txt
echo .
echo .
echo Which B-17G was/will be flown? 
echo 1.Fearless Fosdick (91st BG)
echo 2.Fuddy Duddy (91st BG)
echo 3.Fearless Fosdick (A2A Group)
echo 4.Fuddy Duddy (A2A Group)
echo 5.Another Paint - Non-specific DAT file
echo 6.Display current file and Exit
 
:invalid_choice
set /p choice=enter your choice: 
if %choice%==1 goto Paint1
if %choice%==2 goto Paint2
if %choice%==3 goto Paint3
if %choice%==4 goto Paint4
if %choice%==5 goto OTHER
if %choice%==6 goto GoOut
echo invalid choice: %choice%
goto invalid_choice
 
REM Change the sub-folder names below to match your setup

:Paint1
cd Fearless-Fosdick 91st BG
goto Direction

:Paint2
cd Fuddy-Duddy 91st BG
goto Direction

:Paint3
cd Fearless-Fosdick
goto Direction

:Paint4
cd Fuddy-Duddy
goto Direction

:OTHER
cd other
echo Load or Save the 'other' DAT file? 
echo 1.Load
echo 2.Save

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto DoIt
echo invalid choice: %choice%

:DoIt
copy ..\b17log.dat  /Y
copy loaded_now.txt .. /y
echo The current DAT file has been saved as the 'other' file!
goto GoOut

:Direction
echo Load or Save the DAT file? 
echo 1.Load
echo 2.Save

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto Save_it
echo invalid choice: %choice%
goto Direction

:Load_it
color 27
@echo off
copy b17log.dat .. /y
copy loaded_now.txt .. /y

REM Change the path below for your system

CD \Users\Gypsy Baron\Documents\A2A\FSX\B17
echo The B-17G file...
goto GoOut:

:Save_it
color 17
@echo off
comp ..\f1.txt loaded_now.txt /A
IF NOT ERRORLEVEL 1 goto FileOK
color 47
echo DAT file mismatch! No file saved!
pause
goto start
exit

:FileOK
color 27
type ..\loaded_now.txt
echo and will be saved.
copy ..\b17log.dat  /Y

REM Change the path below for your system

CD \Users\Gypsy Baron\Documents\A2A\FSX\B17
echo The current B-17G file was saved!

:GoOut
type loaded_now.txt
pause
exit

Follow the instructions in the REM's to create the required sub-folders that will contain your saved DAT files and the requred housekeeping text file in each sub-folder.

As always, proceed at you own risk.

[Nico081]

I guessed that I wasn't the first to have thought of this, but couldn't find anything here on the forum on it.
Glad to hear that there may be a way of doing this.

I will try what you described, though I'm not exactly sure what you meant. Are there any other posts here on the forum describing this?

Thanks,
Erik

Hi Erik,

that is what i am also requesting after every accusim release since i am customer (P47) here in the forum.
On one side we have well done accusim innovations which are done outside of fsx, on the other side we have missing automatation managing the dat files for every repaint.
Still got some staff answers in the past but i will further go on requesting to have all data automatic saved by repaint.
Especially with accusim technology and its various wear calculations makes it necessary to have independent states per paint. To manage the aircraft different ways, listen to it and use different aircraft paints for different missions calls for a solution. The meaning of accusim and not having individual aircraft states automaticly does not fit together in my opinion.

At my customer point of view that is an issue i also want to have solved in the future.