Different states between Cherokee 180 Variants

Post any technical issues here. This forum gets priority from our staff.
new reply
knightfire_2001
Airman
Posts: 26
Joined: 16 Oct 2014, 02:24

Different states between Cherokee 180 Variants

Post by knightfire_2001 »

Hi A2A Support Team,
I bought myself the Cherokee 180 as a Christmas present and must say how impressed I am with the aircraft! I love the walkaround procedure especially. Carenado etc have a lot of catching up to do to compete with you!

I have a question on how the "used" state works with the Cherokee: with one of the variants (Factory Red) I've put about 2.5 hrs on the airframe. I wanted to try the "used" state, so switched to another variant (Factory Blue) and changed it to the "used" state, all good so far. However, when I switch back to the Factory Red one, it is also now in the "used" state, you can only reset back to new, erasing my 2.5hrs total time on it.
I was hoping each variant could be kept in a different "state", like you can between the different A2A Spitfires. Is this possible?

Many thanks,
Marcus
Image
Image
Image

Gypsy Baron
A2A Master Mechanic
Posts: 3396
Joined: 02 Aug 2008, 17:04
Location: San Francisco

Re: Different states between Cherokee 180 Variants

Post by Gypsy Baron »

knightfire_2001 wrote:Hi A2A Support Team,
I bought myself the Cherokee 180 as a Christmas present and must say how impressed I am with the aircraft! I love the walkaround procedure especially. Carenado etc have a lot of catching up to do to compete with you!

I have a question on how the "used" state works with the Cherokee: with one of the variants (Factory Red) I've put about 2.5 hrs on the airframe. I wanted to try the "used" state, so switched to another variant (Factory Blue) and changed it to the "used" state, all good so far. However, when I switch back to the Factory Red one, it is also now in the "used" state, you can only reset back to new, erasing my 2.5hrs total time on it.
I was hoping each variant could be kept in a different "state", like you can between the different A2A Spitfires. Is this possible?

Many thanks,
Marcus
Out of the box, the A2A DAT file (that save the state/hours etc) is common to all the aircraft of a type or model.
In the case of the Spitfires, there is a separate DAT file for each MODEL...MkIa, MkIIa, MkIIb. The paints whithin
each model type share a common DAT file.

To keep separate hours/states for each 'paint' you need to do some shuffling and saving/loading of DAT files.

I have created batch files for all my A2A aircraft that load/save the DAT files for each paint, keeping the
DAT file copies in separate folders withing the A2A folder for each aircraft such as:

My Documents/A2A/FSX/Cherokee180

then located in the Cherokee folder are folders for each paint to hold the dat file for that paint.

A small text file is in each paint folder and is used in the load/save process.

Below is the BAT file I use for the Cherokee, that saves the 3 default paints plus provisions for a 4th paint.

The comments in the file need to be read and the initial setup performed before the operations will work properly.

To read those comments first save the full text as a TXT file so it can be opened in Notepad. Once the
setup has been accomplished, the file can then be saved as a BAT (batch file) and when double-clicked
will run the Load/Save batch file. I save the file as "P180 Load_Save.bat" . It must be saved to the
"My Documents/A2A/FSX/Cherokee180" folder where A2A saves the dat file.

I put a shortcut on my desktop to run the file before I fly one of the Cherokees and again after I fly to save the
state of that particular aircraft.

Code: Select all

@echo off
REM This batch file will save or load one of five different A2A Piper 180 DAT files.
REM Place this batch file in your "\Documents\A2A\FSX\Cherokee180" and create a shortcut
REM to be placed on your desktop.

REM Sub-folders in the A2A\FSX\Cherokee180 folde and text files must be created first before
REM running the BAT file the first time.

REM Create a sub-folder for each P180 paint you wish to save in the A2A\FSX\Cherokee180  folder.
REM This program, by default, uses:  C-GGFT, G-KELS, N3572T, and other.

REM In each sub-folder create a text file named "Loaded_Now.txt" that ID's the paint.
REM Example: ..P180 C-GGFT is loaded now!  or ...P180 N3572T is loaded now!
REM  (note the preceeding ".." characters, explained below)

REM NOTE: The text files should be of different sizes so,that the COMP command does
REM            not display each character  difference but only "Files are different sizes!"
REM            I just preceed the actual text with "." characters as needed to make the files different sizes. 
REM            Spaces added at the end will work as well. The file name must be "Loaded_Now.txt"

REM  A file named "f1.txt" and one named "Loaded_Now.txt" will be created in the 
REM  A2A\FSX\Cherokee180  folder the first time this file is run. These files are used
REM to prevent the current file from being saved in the wrong folder. 
REM The "OTHER"  option allows the current file to be unconditionally saved in the "Other" folder

REM This file has been tested on my Win7 Pro x64 system and works properly.
REM Use at your own risk. Backup your current DAT files as necessary. 
REM Created by Paul 'Gypsy Baron' Strogen - December 09, 2014

title Load or Save A2A Cherokee180 

REM  This file assumes that it is located in your "\My Documents\A2A\FSX\Cherokee180"
REM where the Cherokee180 DAT files are located.

@echo off
:start 
color 37
cls
echo This BAT file will Load or Save the A2A Cherokee 180 DAT file

REM Save the current 'loaded now' text file for comparison later
type loaded_now.txt >f1.txt
echo .

REM Display the currently loaded dat file
type loaded_now.txt
echo .
echo .
echo Which P180 was/will be flown? 
echo 1.C-GGFT
echo 2.G-KELS
echo 3.N3572T 
echo 4.Another Paint  - Non-specific DAT file
echo 5.Display the current file and Exit
 
:invalid_choice
set /p choice=enter your choice: 
if %choice%==1 goto Paint1
if %choice%==2 goto Paint2
if %choice%==3 goto Paint3
if %choice%==4 goto OTHER
if %choice%==5 goto GoOut
echo invalid choice: %choice%
goto invalid_choice
 
REM Change the sub-folder names below ( cd N990CP, etc ) to match your setup

:Paint1
cd C-GGFT
goto Direction

:Paint2
cd G-KELS
goto Direction

:Paint3
cd N3572T
goto Direction

:OTHER
cd other

echo Load or Save the 'other' DAT file? 
echo 1.Load
echo 2.Save
color 17

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto DoIt
echo invalid choice: %choice%

:DoIt
copy ..\Cherokee180Log.dat  /Y
copy loaded_now.txt .. /y
echo The current DAT file has been saved as the 'other' file!
goto GoOut

:Direction
echo Load or Save the DAT file? 
echo 1.Load
echo 2.Save

set /p choice=enter your choice: 
if %choice%==1 goto Load_it
if %choice%==2 goto Save_it
echo invalid choice: %choice%
goto Direction

:Load_it
color 27
@echo off
copy Cherokee180Log.dat .. /y
copy loaded_now.txt .. /y

REM Step back to the Cherokee180 directory
CD ..
echo The Cherokee file...
goto GoOut:

:Save_it
color 17
@echo off
echo N | comp ..\f1.txt  loaded_now.txt  /A  
IF NOT ERRORLEVEL 1 goto FileOK
color 47
echo DAT file mismatch! No file saved!
REM Step back to the Cherokee180 directory
CD ..
pause
goto start
exit

:FileOK
color 27
type ..\loaded_now.txt
echo and will be saved.
copy ..\Cherokee180Log.dat  /Y

REM Step back to the Cherokee180 directory
CD ..
echo The current Cherokee file was saved!

:GoOut
type loaded_now.txt
pause
exit
Be sure to follow the instructions in the REM lines to set up the necessary conditions for use.

EDIT: TYPOS FIXED - CHANGED REFERENCES TO C182 to P180 - 12:42 PST 12/28/14

Paul

Image
Last edited by Gypsy Baron on 28 Dec 2014, 15:42, edited 1 time in total.

stevekirks
Senior Airman
Posts: 119
Joined: 27 May 2014, 13:26

Re: Different states between Cherokee 180 Variants

Post by stevekirks »

Gypsy Baron wrote:I have created batch files for all my A2A aircraft that load/save the DAT files for each paint, keeping the DAT file copies in separate folders withing the A2A folder...
Hey A2A Team--could this be more formally implemented in something like input configurator? It would scan for new repaints, generate DAT files and help you swap them out before flights...

Steve
Steve Kirks
KSGF
ImageImage

User avatar
Jacques
Senior Master Sergeant
Posts: 2376
Joined: 26 Jun 2011, 17:54
Location: West Coast, USA

Different states between Cherokee 180 Variants

Post by Jacques »

Hi Paul and Steve,

Steve, I can vouch for the nifty little program Paul has provided above. It is very simple and easy to use, you just need to spend a bit of time for housekeeping and editing the text to suit your needs.


Paul, I think you've mixed your Piper in with your Cessna 182 within the example above. That could be a bit confusing for someone who hasn't used your batch program yet! Amazing stuff, though. Thanks, as always.

Gypsy Baron
A2A Master Mechanic
Posts: 3396
Joined: 02 Aug 2008, 17:04
Location: San Francisco

Re: Different states between Cherokee 180 Variants

Post by Gypsy Baron »

Jacques wrote:Hi Paul and Steve,
-SNIP-

Paul, I think you've mixed your Piper in with your Cessna 182 within the example above. That could be a bit confusing for someone who hasn't used your batch program yet! Amazing stuff, though. Thanks, as always.
Jacques, good eyes!! Thanks for catching those "C182" references. I must have overlooked those when I
'cloned' my C182 files to create the P180 file.

I corrected the typos in my post above. Now off to scan my other bat files to see if anything slipped through
in those. I did, however, test each of the files I created and they worked as planned in spite of the typos, which
didn't affect the procedures themselves.

EDIT: This file doesn't save the "dat.f" file yet. That file saves the frequencies that were set for the aircraft. I'll
get around to adding that at a later date. I'm a bit overloaded at the moment with other FSX things.

Paul

Image

knightfire_2001
Airman
Posts: 26
Joined: 16 Oct 2014, 02:24

Re: Different states between Cherokee 180 Variants

Post by knightfire_2001 »

Hi Paul,
Thanks for the information and the batch file. will give it a go. Will let you know how I get on.

I agree with Steve, if the A2A Team could include this feature as standard for the Cherokee, that would be great as I like to have my "new" plane, but also be able to jump into a "used" club plane if I'm flying from another airfield.

Cheers,
Marcus
YTYA
Image
Image
Image

knightfire_2001
Airman
Posts: 26
Joined: 16 Oct 2014, 02:24

Re: Different states between Cherokee 180 Variants

Post by knightfire_2001 »

Hi Paul,
I've installed and run your batch file and it works! Thanks for sharing that with me.

I just need to remember to run the batch to save the DAT file after each flight and load it before I fly.

Happy New Year!
Cheers,
Marcus
YTYA
Image
Image
Image

User avatar
Lewis - A2A
A2A Lieutenant Colonel
Posts: 33284
Joined: 06 Nov 2004, 23:22
Location: Norfolk UK
Contact:

Re: Different states between Cherokee 180 Variants

Post by Lewis - A2A »

Its worth noting that there is only one Cherokee variant but you mean repaints. The Spitfire has 3 variants, the MkI, II and IIB.

As well as the handy tool you can also move the files manually, the .dat files are located in you my docs >> A2A folder for each of your aircraft.

A tool is being looked into, but scanning the cfg for repaints given the user changes isn't the easiest thing to create without it getting messy as soon as you start adding or changing repaints etc. Our lead artist ROB has been at the coding books recently and is creating some handy little tools internally that might see general user use down the road.

thanks,
Lewis
A2A Facebook for news live to your social media newsfeed
A2A Youtube because a video can say a thousand screenshots,..
A2A Simulations Twitter for news live to your social media newsfeed
A2A Simulations Community Discord for voice/text chat

Gypsy Baron
A2A Master Mechanic
Posts: 3396
Joined: 02 Aug 2008, 17:04
Location: San Francisco

Re: Different states between Cherokee 180 Variants

Post by Gypsy Baron »

The 'messy' Lewis refers to is that a general purpose tool that looked at all th cfg entries, etc
would most likely involve 'self-modifying code'. That is an area any programmer in his pr her right mind
would stay away from :)

Paul

User avatar
mgr
Staff Sergeant
Posts: 397
Joined: 07 May 2006, 03:18

Re: Different states between Cherokee 180 Variants

Post by mgr »

Hiya Lewis,
Lewis - A2A wrote:Its worth noting that there is only one Cherokee variant but you mean repaints. The Spitfire has 3 variants, the MkI, II and IIB.
As well as the handy tool you can also move the files manually, the .dat files are located in you my docs >> A2A folder for each of your aircraft.
A tool is being looked into, but scanning the cfg for repaints given the user changes isn't the easiest thing to create without it getting messy as soon as you start adding or changing repaints etc. Our lead artist ROB has been at the coding books recently and is creating some handy little tools internally that might see general user use down the road.
thanks,
Lewis
Maybe a more simpler approach?
- One default dat-file (as now)
- Via the "maintenance hanger" a option to start a new livery specific dat-file for the aircraft loaded at that time. (creating a livery specific dat-file) Think you can couple the dat-file on the "title" in the aircraft.cfg, FSX would not allow multiple entries with the same name.

If you decide to make such a option, please make it for ALL options of the "maintenance hanger", wheelcovers etc, so you can really tune every livery you have.

Really hope you consider this for a new update!

Thx,

Marcel
Image

Gypsy Baron
A2A Master Mechanic
Posts: 3396
Joined: 02 Aug 2008, 17:04
Location: San Francisco

Re: Different states between Cherokee 180 Variants

Post by Gypsy Baron »

Marcel,

The dat file loaded will affect what is displayed in the maintenance hangar since the
dat file contains all that information...aircraft /engine hours, maintenance state, options, etc.

Paul

User avatar
caleb1
Senior Airman
Posts: 215
Joined: 15 Dec 2016, 18:44

Re: Different states between Cherokee 180 Variants

Post by caleb1 »

Would I need to run it after I fly the aircraft or only before?

Thanks much
Caleb Byers

A2A Hanger: C182, C172, PA-28, PA-24, J3

PC: Intel Core i7 6700 @ 3.4 GHz to 4.0 GHz, 24GB RAM, GTX 745 with 4GB VRAM, 2TB SSHD, Win 10 Home x64.

Simulators: P3D v3.4, P3D v4.5, FSX:SE

Real Hanger at FD08: 1956 C172, 1964 PA-24 400

new reply

Return to “Piper Cherokee 180 Tech Support”

Who is online

Users browsing this forum: No registered users and 8 guests